כותרת בהערת שוליים

[vtri]

יש אפשרות שWORD יכניס באופן אוטומטי כותרת להערת שוליים.(פירוט: במסמך יש שלש כותרות, בטקסט שמתחת לכותרת אני שם הפניה להערת שוליים, וככה גם בכותרת השניה. האם יש אפשרות שבהערת שולים יהיה גם את הכותרת שמופיעות למעלה).

עוד דבר שאחרי כל כותרת המספור של הערות תתחיל מחדש.
תודה רבה לעוזרים

____________
משנכנס אדר מרבים בשמחה :-C

 

[Rרחמים]

עוד דבר שאחרי כל כותרת המספור של הערות תתחיל מחדש.

צריך להוסיף מעברי מקטע לפני כל כותרת ולהגדיר בהגדרות ההערות שוליים למספר מחדש בכל מקטע.

 

[kap]

לגבי המספרים כמו שרחמים אמר.

לגבי הכותרות בהערת שוליים, לכאורה אפשר כך:

לסמן את הכותרת הרצויה בסגנון מסויים. לעבור לתצוגת טיוטה, ושם, תחת "הפניות" לבחור "הצג הערות". תופיע חלונית של הערות השוליים. לבחור במקום "כל הערות השוליים" את "מפריד הערות שוליים".
בשורה חדשה תחת המפריד לשים STYLEREF של הסגנון הנבחר (עם סימון "חפש מתחתית הדף למעלה" כמובן).

 

[vtri]

זה טוב רק עם יש לי כותרת אחת בעמוד, אבל ברגע שיש לי כמה כותרת בעמוד אחד. איך אני עושה שלכל כותרת שמופיעה בדף למעלה... יהיה גם למטה בהערות שוליים קודם את הכותרת ואח"כ את הערות ששייכות לאותה כותרת...

 

[mizzan]

אתה לא מסביר ברור, למה אתה צריך כותרת להערת שוליים אם יש מספרים להערות
לא ניתן ליצור יותר מכותרת אחת להערות שולים בכל מקטע

 

[vtri]

לא ניתן ליצור יותר מכותרת אחת להערות שולים בכל מקטע

יצא לי לראות בעבר ספר שיש בו כותרות בהערות שולים...

 

[vtri]

איך אני עושה דבר כזה?.. הערה 2 שייכת לכותרת מספר 1 והערה 6 שייכת לכותרת מספר 2 איך אני עושה שלפני הערה 2 יהיה את הכותרת מספר 1 ולפני הערה 6 יהיה את כותרת מספר 2 וכן הלאה... (כמו שמופיע בעיגולים הירוקים)
תודה מראש!!

 

[Rרחמים]

אני חושב שמוכרחים לזה מאקרו, או שתעשה את זה ידנית אם זה לא הרבה כותרות.

 

[vtri]

יש כזה מאקרו מוכן?

 

[Rרחמים]

אני לא מכיר מוכן, אבל אם הבנתי אותך נכון זה לא כל כך מסובך רק שהמאקרו:
1. יעבור על כל הכותרות מסגנון מסויים
2. וימצא את ההערה הראשונה שאחר הכותרת
3. ויוסיף לפני ההערה בפסקה חדשה עם טקסט הכותרת.

 

[vtri]

ניסתי לשבור את הראש ולכתוב את המאקרו הזה ולא עלה בידי.... אם זה משהו פשוט מישהוא יכול להושיט יד?

 

[Rרחמים]

בס''ד

תנסה את זה:

Sub test()

    Dim i As Integer
    For i = 1 To ActiveDocument.Paragraphs.Count
        ' בודק אם הפסקה בסגנון כותרת
        If ActiveDocument.Paragraphs(i).Style = "כותרת 2" Then
            Dim txt As String
            txt = ActiveDocument.Paragraphs(i).Range.Text
            ' מתקדם לפסקה שיש בה הערה
            Do While ActiveDocument.Paragraphs(i).Range.Footnotes.Count = 0
                i = i + 1
            Loop
            ' מוסיף את טקסט הכותרת לפני ההערה
            ActiveDocument.Paragraphs(i).Range.Footnotes(1).Range.Select
            Selection.HomeKey wdLine
            Selection.TypeText txt
        End If
    Next

End Sub

 

[vtri]

ממש תודה רבה! זה עושה מושלם את הכותרת אבל את המיספור מחדש בכל כותרת הוא לא עושה. איך אפשר לעשות את זה?

 

[Rרחמים]

בס''ד

תנסה את זה:

Sub test()

    ' מתחיל מספור הערות מחדש בכל מקטע
    ActiveDocument.Range.FootnoteOptions.NumberingRule = wdRestartSection

    Dim i As Integer
    For i = 1 To ActiveDocument.Paragraphs.Count
        ' בודק אם הפסקה בסגנון כותרת
        If ActiveDocument.Paragraphs(i).Style = "כותרת 2" Then
            Dim txt As String
            txt = ActiveDocument.Paragraphs(i).Range.Text
            ' מוסיף מעבר מקטע רציף
            ActiveDocument.Paragraphs(i).Range.InsertBreak wdSectionBreakContinuous
            ' מתקדם לפסקה שיש בה הערה
            Do While ActiveDocument.Paragraphs(i).Range.Footnotes.Count = 0
                i = i + 1
            Loop
            ' מוסיף את טקסט הכותרת לפני ההערה
            ActiveDocument.Paragraphs(i).Range.Footnotes(1).Range.Select
            Selection.HomeKey wdLine
            Selection.TypeText txt
        End If
    Next

End Sub

 

[vtri]

שוב תודה, המספור עובד מעולה.
אבל...
למה אחרי מקטע, וורד מעביר לעמוד הבא?
(הסבר: המספור עובד לפי מקטע, ומתי שמוסיפים עוד מקטע, ויש הערות שולים בשניהם אוטומטי הוא מעביר לעמוד הבא.)

 

[Rרחמים]

בס''ד

תנסה את המאקרו הבא, הוא ללא מעברי מקטע ובכל זאת המספור מתחיל מחדש אחרי כל כותרת:

Sub test()

    Dim myStyle As String: myStyle = "כותרת 2"

    Dim i As Integer
    For i = 1 To ActiveDocument.Paragraphs.Count
        ' בודק אם הפסקה בסגנון כותרת
        If ActiveDocument.Paragraphs(i).Style = myStyle Then
            Dim txt As String
            txt = ActiveDocument.Paragraphs(i).Range.Text
            ' מתקדם לפסקה שיש בה הערה
            Do While ActiveDocument.Paragraphs(i).Range.Footnotes.Count = 0
                i = i + 1
            Loop
            Dim first As Integer: first = i

            ' ממספר את ההערות
            Dim num As Integer: num = 1
            Do
                Dim j As Integer
                For j = 1 To ActiveDocument.Paragraphs(i).Range.Footnotes.Count
                    ActiveDocument.Footnotes.Add ActiveDocument.Paragraphs(i).Range.Footnotes(j).Reference, CStr(num), ""
                    num = num + 1
                Next
                i = i + 1
                If i > ActiveDocument.Paragraphs.Count Then Exit Do
            Loop While ActiveDocument.Paragraphs(i).Style <> myStyle

            ' מוסיף את טקסט הכותרת לפני ההערה הראשונה
            ActiveDocument.Paragraphs(first).Range.Footnotes(1).Range.Select
            Selection.HomeKey wdLine
            Selection.TypeText txt

            i = i - 1
        End If
    Next

End Sub

 

[vtri]

יש אפשרות לעשות שהכותרות שבתוך הערות שוליים לא יהיו בסגנון של כתב עילי?
אני הצלחתי לעשות משהו כזה על ידי חיפוש והחלפה, השאלה היא אם אפשר לעשות את זה כחלק מאמאקרו....

 

[Rרחמים]

בס''ד

אפשר כך:

Sub test()

    Dim myStyle As String: myStyle = "כותרת 2"

    Dim i As Integer
    For i = 1 To ActiveDocument.Paragraphs.Count
        ' בודק אם הפסקה בסגנון כותרת
        If ActiveDocument.Paragraphs(i).Style = myStyle Then
            Dim txt As String
            txt = ActiveDocument.Paragraphs(i).Range.Text
            ' מתקדם לפסקה שיש בה הערה
            Do While ActiveDocument.Paragraphs(i).Range.Footnotes.Count = 0
                i = i + 1
            Loop
            Dim first As Integer: first = i

            ' ממספר את ההערות
            Dim num As Integer: num = 1
            Do
                Dim j As Integer
                For j = 1 To ActiveDocument.Paragraphs(i).Range.Footnotes.Count
                    ActiveDocument.Footnotes.Add ActiveDocument.Paragraphs(i).Range.Footnotes(j).Reference, CStr(num), ""
                    num = num + 1
                Next
                i = i + 1
                If i > ActiveDocument.Paragraphs.Count Then Exit Do
            Loop While ActiveDocument.Paragraphs(i).Style <> myStyle

            ' ניגש להערה הראשונה
            ActiveDocument.Paragraphs(first).Range.Footnotes(1).Range.Select
            With Selection
                .HomeKey wdLine
                ' מעצב גופן לפני הוספת הכותרת
                .Font.Superscript = False
                ' מוסיף את טקסט הכותרת
                .TypeText txt
            End With
            i = i - 1
        End If
    Next

End Sub

 

[vtri]

תודה רבה Rרחמים על כל העזרה... ב"ה זה עובד מעולה

 

[Rרחמים]

אני מאוד שמח

אולי אשכלל את זה לתוסף מסודר עם ממשק ואפשרויות מתקדמות ואוסיף לקטלוג.