שינוי כל הטקסט בקובץ שבעקוב אחרי שינוים יחד

[משתדל1]

קיבלתי קובץ וורד של מאות עמודים לעריכה.
הקובץ מורכב מטקסט מקור שעליו עבד מישהו בעקוב אחרי שינויים והוסיף המון חומר לכל אורך הקובץ בין השורות והקטעים אין ספור פעמים.
אני מעוניין שטקסט המקור יהיה בגופן מסויים ובגודל מסויים שונה מהגופן והגודל של הטקסט מקור שבקובץ.
כמובן שאני יכול לעבור כל תוספת שמסומנת בעקוב ולשנות אותה למה שאני רוצה, אבל זה המון עבודה, האם יש דרך לתת הוראת החלפה לכל הטקסט שבעקוב שיוחלף סוג וגודל הגופן?
יש ב'החלף' המון אופציות את מה להחליף ובהם כל מה שצבוע למשל באדום אבל הטקסט שבעקוב לא באמת צבוע באדום רק נראה כך וההחלף לא מזה אותו כמשהו שונה שאתן פקודה כללית כלכ העקוב, משער שיש דרך אשמח ללמוד מה היא.
תודה מראש
מצורף קובץ דוגמא סתמית שהכנתי כדי שיהיה ברור על מה אני מדבר.

 

[בית הסופר התורני]

מה שעולה לי כעת:
סקירה> במקום 'כל הסימונים' תחליף ל'מקור'.
ואז תשנה את הצבע של כל הטקסט הקיים.
לאחר מכן תחליף בחזרה ל'כל הסימונים'. קיבלת בעצם את הטקסט ב-2 צבעים.
כעת תבחר מילה אחת מאחד מהטקסטים, וב-בית>בחר>בחר את כל הטקסט עם עיצוב דומה.
ואז תשנה בדיוק למה שאתה רוצה.

 

[משתדל1]

מה שעולה לי כעת:
סקירה> במקום 'כל הסימונים' תחליף ל'מקור'.
ואז תשנה את הצבע של כל הטקסט הקיים.
לאחר מכן תחליף בחזרה ל'כל הסימונים'. קיבלת בעצם את הטקסט ב-2 צבעים.
כעת תבחר מילה אחת מאחד מהטקסטים, וב-בית>בחר>בחר את כל הטקסט עם עיצוב דומה.
ואז תשנה בדיוק למה שאתה רוצה.

או שלא הבנתי אותך נכון או שזה לא עוזר
עשיתי לפי מה שהבנתי שכתבת, והשינוי של הצבע למרות שמופיע רק המקור, בעצם משנה את כל המסמך יחד, גם את מה שבעקוב ואינו נראה כרגע, הוא קיים במסמך ולכן משתנה יחד עם המקור למרות שאינו נראה, כשאני מחזיר לכל הסימונים כל הטקסט מקור ותוספות שבעקוב השתנו יחד.

 

[סוגרים שידוך]

בגירסה באנגלית של וורד יש אפשרות לבחור בהחלף את כל הטקסט הנוסף בעקוב מה שלא נמצא בגירסא בעברית
להלן מקארו שבאמצעותו ניתן לשנות בלחיצה אחת את כל הטקסט הנוסף בעקוב לגופן וגודל אחר

Sub ApplyFontToInsertedRevisions()
    On Error GoTo ErrHandler
    Dim r As Revision
    Dim fontName As String
    Dim fontSizeInput As String
    Dim fontSize As Single
    Dim count As Long

    Application.ScreenUpdating = False

    fontName = InputBox("הכנס שם גופן לדוגמה, למשל Arial", "שם גופן")
    If Trim(fontName) = "" Then GoTo Cleanup

    fontSizeInput = InputBox("הכנס גודל גופן במספרים, למשל 12", "גודל גופן")
    If Trim(fontSizeInput) = "" Then GoTo Cleanup
    fontSize = Val(fontSizeInput)
    If fontSize <= 0 Then
        MsgBox "גודל לא תקין", vbExclamation
        GoTo Cleanup
    End If

    count = 0
    For Each r In ActiveDocument.Revisions
        If r.Type = wdRevisionInsert Then
            With r.Range.Font
                .Name = fontName
                .Size = fontSize
            End With
            count = count + 1
        End If
    Next r

    MsgBox "שונו עיצוב ל " & count & " הוספות", vbInformation

Cleanup:
    Application.ScreenUpdating = True
    Exit Sub

ErrHandler:
    MsgBox "אירעה שגיאה: " & Err.Description, vbCritical
    Resume Cleanup
End Sub

 

[משתדל1]

בגירסה באנגלית של וורד יש אפשרות לבחור בהחלף את כל הטקסט הנוסף בעקוב מה שלא נמצא בגירסא בעברית
להלן מקארו שבאמצעותו ניתן לשנות בלחיצה אחת את כל הטקסט הנוסף בעקוב לגופן וגודל אחר

Sub ApplyFontToInsertedRevisions()
    On Error GoTo ErrHandler
    Dim r As Revision
    Dim fontName As String
    Dim fontSizeInput As String
    Dim fontSize As Single
    Dim count As Long

    Application.ScreenUpdating = False

    fontName = InputBox("הכנס שם גופן לדוגמה, למשל Arial", "שם גופן")
    If Trim(fontName) = "" Then GoTo Cleanup

    fontSizeInput = InputBox("הכנס גודל גופן במספרים, למשל 12", "גודל גופן")
    If Trim(fontSizeInput) = "" Then GoTo Cleanup
    fontSize = Val(fontSizeInput)
    If fontSize <= 0 Then
        MsgBox "גודל לא תקין", vbExclamation
        GoTo Cleanup
    End If

    count = 0
    For Each r In ActiveDocument.Revisions
        If r.Type = wdRevisionInsert Then
            With r.Range.Font
                .Name = fontName
                .Size = fontSize
            End With
            count = count + 1
        End If
    Next r

    MsgBox "שונו עיצוב ל " & count & " הוספות", vbInformation

Cleanup:
    Application.ScreenUpdating = True
    Exit Sub

ErrHandler:
    MsgBox "אירעה שגיאה: " & Err.Description, vbCritical
    Resume Cleanup
End Sub

תודה רבה